【溫馨提示】親愛的朋友，閱讀之前請您點擊【關注】，您的支持将是我最大的動力！

Excel表格中數據求和，可以說最常的數據計算操作。我們都知道普通求和用快捷鍵最方便，也有SUM函數，按條件求和用SUMIF函數，多條件求和用SUMIFS函數。

那麼你知道按條件多列求和怎麼操作呢？今天阿鐘老師分享幾個函數公式來解決，各具特色，看看你的工作中需要哪一種？

實例：下圖表格中，要求計算各産品的前三個月銷量合計數；

分析：求和的條件産品在B列，求和的數據區域在C、D、E三列。

01：

=SUMIF(B:B,G2,C:C) SUMIF(B:B,G2,D:D) SUMIF(B:B,G2,E:E)

這個公式不難理解，就是三個SUMIF函數分别對C、D、E三列求和後再相加，得出計算結果。

02：

=SUM(IF(B$2:B$13=G2,C$2:E$13))

注意：這是一個數組函數，公式輸入完成後要按Ctrl Shift 回車鍵确認公式，再雙擊或下拉填充公式。

公式利用IF函數判斷滿足條件的數據，再用SUM函數實現求和。

03：

=SUM((B$2:B$13=G2)*C$2:E$13)

這也是一個數組公式，需要按Ctrl Shift 回車鍵确認公式，再雙擊或下拉填充公式。

這個公式與上一個比較省了IF函數判斷，利用B$2:B$13=G2産生的邏輯值（0和1）與數據區域相乘。

04：

=SUMPRODUCT((B$2:B$13=G2)*C$2:E$13)

這個公式原理和上一個一樣，區别在于回車鍵确認公式即可，省去三鍵确認的麻煩。

以上公式比較簡單，也能滿足日常工作需求。

接下來講的公式相對有些難度，如果喜歡函數公式的可以繼續看下去。

05：

=SUMPRODUCT((B$2:B$13=G2)*MMULT(C$2:E$13,{1;1;1}))

06：

=SUM(MMULT((B$2:B$13=G2)*C$2:E$13,{1;1;1}))

這兩個公式比較相似，弄懂的話需要先看看MMULT函數的用法。

MMULT函數

【用途】計算兩個數組的矩陣乘數

【語法】MMULT（數組1，數組2）

07：

=SUM(SUMIF(B:B,G2,OFFSET(B:B,,{1,2,3})))

這個公式利用OFFSET函數對求和數據區域偏移，構造多區域數據，分别得到三列的求和。

08：

=SUM(SUMIF(B:B,G2,INDIRECT("C"&{3,4,5},)))

與上一公式相似，用INDIRECT函數構造多區域數據。

09：

=SUM(SUMIF(B:B,G2,INDIRECT({"C","D","E"}&1)))

和上一公式相同，INDIRECT函數換了一種單元格引用方式。

10：

=SUM(DSUM(A$1:E$13,{3,4,5},G$1:G2))-SUM(H$1:H1)

公式中DSUM函數為數據庫類的求和函數，計算數據庫中指定條件的記錄之和。

11：

=SUMPRODUCT(COUNTIF(G2,B$2:B$13)*C$2:E$13)

公式中利用COUNTIF函數來判斷，類似02公式中的IF函數判斷。

12：

=MMULT(MMULT(N(G2:G6=TRANSPOSE(B2:B13)),C2:E13),{1;1;1})

數組公式，并且需要先選中結果區域H2：H6，輸入公式後按Ctrl Shift 回車鍵确認公式，得出計算結果，不必再雙擊或下拉填充公式。較難理解，關注我後面的教程陸續推出詳細教程。

小夥伴們，在使用Excel中還碰到過哪些問題，評論區留言一起讨論學習，堅持原創不易，您的點贊轉發就是對小編最大的支持，更多教程點擊下方專欄學習。

更多精彩资讯请关注tft每日頭條，我们将持续为您更新最新资讯!