小夥伴們好啊~

不知道小主們是否遇到過這種事：一個簡單的關鍵詞回複，居然錯了一兩千人，本來可以自動回複，卻演變成手工複制粘貼，浪費了不必要的時間...

所以呀，本周為各位帶來兩個表格操作技巧：一招搞定庫存彙總&會計對賬不加班的秘密，加班什麼的根本不存在。

小主們，心動嗎？

趕緊收藏看起來~

一、一招搞定庫存彙總

庫存表這個大部分公司都會用到，隻是形式不同而已。今天，為小主們講解一下庫存表。

1.明細表

每個地區的庫存表格式一樣，第2行為彙總數據，第4行為工廠。第2行本來是沒有公式的，盧子這裡增加一條公式，方便統計。在B2輸入公式，向右拖動。

=SUM(B5:B998)

2.彙總表

根據明細表，将每個地區每個工廠的數量進行彙總。

正常查找引用都是用VLOOKUP函數，不過這裡的明細表格式不支持，查找區域在明細表第4行，返回區域在明細表第2行。

其實，VLOOKUP函數有一個超級牛逼的兄弟，叫LOOKUP函數。這個函數360°無死角，通通可以查找。記住這個函數的語法：

=LOOKUP(1,0/(查找值=查找區域),返回區域)

現在要統計華北區，直接套用公式即可，在彙總表B3輸入公式，向右拖動。

=LOOKUP(1,0/(B2=華北區!4:4),華北區!2:2)

同理，東北區可以用公式：

=LOOKUP(1,0/(B2=東北區!4:4),東北區!2:2)

這裡隻是列舉了5個地區，每個地區改一次公式也挺方便的。

現在問題來了，全國可以劃分成好多個地區，如果都這樣改顯得超級繁瑣，而且容易出錯，怎麼辦呢？？

可以這樣做：

剛好每個地區都列在A列，這樣其實就間接給我們提供了地區的名稱，可以進行引用。這裡借助&将工作表名稱跟區域連接起來。

=A3&"!4:4"

不過用&連接起來的隻能算文本，并不是真正的區域，需要嵌套INDIRECT函數才可以真正變成區域。再将剛剛的公式組合起來就基本搞定，還剩下最後一點點細節。

=LOOKUP(1,0/(INDIRECT(A3&"!4:4")=B2),INDIRECT(A3&"!2:2"))

我們在使用公式的時候，需要下拉和右拉，這時該固定的區域别忘了加$，要不然就會出錯。

=LOOKUP(1,0/(INDIRECT($A3&"!4:4")=B$2),INDIRECT($A3&"!2:2"))

當然，這裡可以将公式寫得更加完美，實際上每個地區的工廠可能不一樣，就會導緻一些工廠沒有對應值導緻出錯，比如現在将其中一個工廠改成潮州工廠。

查找不到對應值會顯示錯誤值，隻需再嵌套一個IFERROR函數，即可解決這個問題。

=IFERROR(LOOKUP(1,0/(INDIRECT($A3&"!4:4")=B$2),INDIRECT($A3&"!2:2")),0)

合計就直接用SUM函數就行。

行合計：

=SUM(B3:B7)

列合計：

=SUM(B3:H3)

在寫公式的時候，一定要将公式從最基礎的開始寫，然後一步步改進。千萬别想着一步到位，除非你本身就是高手啦~

二、Excel對賬不加班的真相

1.對賬

會計科目為：謝謝你！，你的會計科目卻是五花八門，看起來一樣，實際卻不同。微信認為不同，Excel也認為不同，隻有人工才認為一樣。兩邊的會計科目不一樣，用Excel如何對賬？

沒法，直接手工一個個審核，這樣不加班才怪。标準化才能提高工作效率，告别加班！

會計科目一樣，在微信是智能回複，在Excel一個VLOOKUP函數也能輕松解決，多麼省事。

=VLOOKUP(D2,A:B,2,0)

用漢字容易出錯，可以使用唯一性的科目代碼，用數字出錯率就會降低。

=VLOOKUP(E2,A:C,3,0)

數字也會出錯，就是兩邊格式不同，一邊為文本格式，一邊為數值格式。不過面對格式不同，對公式略作改變即可解決。

Step 01 左邊是文本格式，右邊是數值格式，可以通過&""解決。

=VLOOKUP(E2&"",A:C,3,0)

Step 02 左邊是數值格式，右邊是文本格式，可以通過--解決。

=VLOOKUP(--E2,A:C,3,0)

2.金額分攤

根據分攤開始月、分攤結束月，将付款金額平均分攤到每個月。

舉個例子，分攤開始月為2017/07，在這個日期之前就不能有分攤金額，分攤結束月為2018/06，在這個日期之後就不能有分攤金額。根據這個條件，可以這樣設置：

=IF(OR($A2>E$1,E$1>$B2),"",分攤金額)

分攤金額就是付款金額除以分攤的總月份，算兩個日期的間隔月份可以用DATEDIF函數。

=DATEDIF($A2,$B2,"m") 1

分攤金額：

=$D2/(DATEDIF($A2,$B2,"m") 1)

好，現在将公式組合起來就是最終結果。

=IF(OR($A2>E$1,E$1>$B2),"",$D2/(DATEDIF($A2,$B2,"m") 1))

切記：将公式從最基礎的開始寫，然後一步步改進~

從此會計對賬經常加班的現象不會再找你。

在這裡相信有許多想要學習會計的同學，大家可以關注小編頭條号，私信【學習】即可免費領取一整套系統的會計學習教程！

更多精彩资讯请关注tft每日頭條，我们将持续为您更新最新资讯!