Hello，大家好，今天跟大家分享一個“跨界函數”的天花闆，他就是REPT函數，它的本意是用于重複字符串，但是如果配合特殊的字體使用，我們工作中常見的甘特圖，旋風圖，瀑布圖等等都可以輕松搞定，今天我們就來get下它的使用方法吧

想要從零學習Excel，這裡↑↑↑↑↑↑

REPT：将指定的文本重複相應的次數

語法：=REPT(text, number_times)

第一參數：需要重複的文本

第二參數:文本重複的次數。必須是一個正數，如果設置為負數，函數會顯示#VALUE!這個錯誤值，如果設置為了一個 小數，函數會向下取整，比如設置為5.8，就會默認将第二參數設置為5，将第一參數重複5次。

下圖就是它的實際效果，當我們将函數的第一參數設置為【我】字，将第二參數設置為6的時候，它輸出的結果就是6個我字，随後我們來看下他能解決哪些問題

1.設置手機号碼保護

公式：=LEFT(A3,3)&REPT("*",4)&RIGHT(A3,4)

在這裡我們使用left函數提取手機号碼的前三位，在使用rigth函數提取手機号碼的後四位，在使用鍊接符号将*号重複4次，最後把它們連接在一起就好了

2.星級判定

公式：=REPT("⭐",B3/15)

這個幸幸符号是用輸入法打出來的，随後将第二參數都除以15，縮小相同的倍數。如果你使用的是win10以上的系統，可以按下Windows鍵 句号，來調出系統自帶的表情符号，制作更多的顯示效果

使用REPT函數制作圖表，我們需要配合Playbill這個字體來構建，幾乎所有以條形圖構建的圖表REPT函數都可以輕松搞定，下面我們就來着手制作下吧

1.條形圖

公式：=REPT("|",A3)&" "&A3

在這裡我們将REPT函數的第一參數設置為了豎線，讓豎線重複多次，在Playbill字體下豎線會被顯示為一個條形，這個就是圖表的制作原理，在REPT函數後面我們分别鍊接了空格與銷量，這個是為了讓銷量與條形圖留有餘量更加好看

2.柱形圖

公式：=REPT("|",B3)&" "&B3

方法與條形圖是一模一樣的，在制作柱形圖的時候我們需要選擇圖形區域，在文字旋轉中選擇【向上旋轉文字】随後将對齊方式設置為【底端對齊】與【居中對齊】

3.瀑布圖與堆積圖

公式：=REPT("|",B3*2)&" "&B3

原理與制作【條形圖】是一模一樣的，我們将數值【降序排序】就是一個【瀑布圖】，将數值【升序排序】就是一個【階梯圖】，在這裡我們将銷量擴大了2倍，讓它看起來更加的和諧，還有一個需要注意的是需要将文字的2個對齊方式都設置為【居中】

4.盈虧圖

虧損公式：=IF(B3<0,B3&" ","")&IF(B3<0,REPT("|",ABS(B3)*5),"")

對齊方式為：居中與右對齊

盈利公式：=IF(B3>0,REPT("|",ABS(B3)*5),"")&IF(B3>0," "&B3,"")

對齊方式為：居中與左對齊

IF函數的作用是根據正負數據返回對應的列，ABS函數它的作用是返回數據的絕對值，利用它可以将負數變為正數放在REPT函數的第二參數中，最後我們将虧損字體設置為紅色，盈利字體設置為綠色即可

5.甘特圖

公式：=REPT(" ",B3-MIN($B$3:$B$6))&REPT("|",D3*8)

函數可以拆分為2個部分來講解

第一部分：REPT(" ",B2-MIN($B$2:$B$5))第一參數設置的是空格，第二參數用開始時間減去最小開始時間，讓最小時間的甘特圖從最左邊開始，并且可以利用這個特性來填充空格

第二部分： REPT("|",D2*8)它的作用是用來重複填充豎線，因為天數太小所以我們将它放大8倍，大家可以根據自己的圖表數據進行放大

6.旋風圖

贊成公式：=B4*100&"%"&" "&REPT("|",B4*200)

對齊方式為：居中以及右對齊

反對公式：=REPT("|",C4*200)&" "&C4*100&"%"

對齊方式為：居中以及左對齊

這個主要是構建後面顯示的百分号，就是B4*100&"%"這個公式，我們先把數據擴大100倍，然後為其連接一個百分号，看起來就是百分比的樣子了~

以上就是今天分享的全部内容，在使用rept與Playbill來構建圖形的時候，我們需要注意的是柱子的顔色是由字體顔色控制的，并不是由填充色控制的

我是Excel從零到一，關注我，持續分享更多Excel技巧

更多精彩资讯请关注tft每日頭條，我们将持续为您更新最新资讯!