以下文章來源于VBA編程學習與實踐 ，作者EH看見星光

我們今天分享的内容是使用VBA代碼實現多條件查詢的功能，照例舉個栗子。

如下圖所示，表名為“明細表”的數據是明細數據。

再如下圖所示，表名為“查詢表”的數據是需要查詢的數據。

現在我們需要根據查詢表的姓名和課目兩個條件，在明細表中查詢相關的成績。

對于VBA來說，處理這樣的問題總是有一個固定的套路，确定條件關系後，将明細數據循環裝入字典，其中明細表的條件作為關鍵字（Key），需要查詢的結果作為條目（Item），最後遍曆查詢表，根據提取相應的結果。

代碼如下：

Sub DicFind()

Dim d As Object, arr, brr, i&, j&, k&, s$

Set d = CreateObject("scripting.dictionary")

'後期引用字典

'd.CompareMode = vbTextCompare

'不區分字母大小寫

arr = Sheets("明細表").[a1].CurrentRegion

'明細數據裝入數組arr

For i = 2 To UBound(arr)

'遍曆數組arr，将數據裝入字典，以備查詢

'标題行不要，從第二行開始遍曆

For j = 2 To UBound(arr, 2)

'标題列不要，從第二列開始遍曆

s = arr(i, 1) & "@" & arr(1, j)

'姓名@課目是查詢條件，作為字典的key值

d(s) = arr(i, j)

'成績是查詢的結果，作為字典的item

Next

Next

brr = Sheets("查詢表").[a1].CurrentRegion

'查詢區域的數據裝入數組brr

For i = 2 To UBound(brr)

s = brr(i, 1) & "@" & brr(i, 2)

'合并查詢的兩個條件成為一個條件字符串，姓名@課目

For j = 3 To UBound(brr, 2)

If d.exists(s) Then

'如果字典中存在變量s

brr(i, j) = d(s)

'從字典中取s對應的條目

Else

brr(i, j) = ""

'否則返回假空

End If

Next

Next

Sheets("查詢表").[a1].CurrentRegion = brr

'将數組brr放回查詢區域

MsgBox "查詢OK"

Set d = Nothing

'釋放字典内存

End Sub

小貼士：

1，對于字典查詢法來說，其實大部分情況下，并不存在多條件查詢的問題，把多個條件合并成一個條件表達式，那就是單條件查詢。

2，需要注意的是，該段代碼區分字母大小寫，也就是說“VBA”并不等同于“vba”，如果需要不區分字母大小寫，取消代碼中以下語句的注釋。

'd.CompareMode =vbTextCompare '不區分字母大小寫

3，留個練手題，使用VBA代碼實現條件求和和計數。

如下圖所示，根據A:B列的數據，計算D列人員的考試次數和考試成績

更多精彩资讯请关注tft每日頭條，我们将持续为您更新最新资讯!