我前不久曾教過大家如何統計區域内符合多個條件的單元格個數，詳情請參閱 Excel – 統計同時滿足多個條件的單元格數，你要用幾個函數？

但是有些同學反饋自己的 Excel 版本比較低，無法使用 countifs 函數，咨詢有沒有低版本函數能替代的公式？

那我今天就教大家幾個 countif 的使用案例。

下圖 1 的 A 至 C 列是各銷售人員每個月的單筆提成記錄，可能每月有多筆提成，也可能沒有。

需要在右側按不同的金額區間統計總提成筆數。

效果如下圖 2 所示。

1. 在 F2 單元格中輸入以下公式：

=SUM(COUNTIF($C$2:$C$24,{">=1000",">=1500"})*{1,-1})

公式釋義：

• COUNTIF($C$2:$C$24,{">=1000",">=1500"})：分别統計出提成大于等于1000 和大于等于 1500 的個數，返回一組數組
• ...*{1,-1}：用上述數組乘以另一個數組 {1,-1}，再次等到一個數組，其中大于等于 1000 的個數為正數，而大于等于 1500 的個數為負數
• 最後用 SUM 函數将數組中的每個數相加，相當于用大于等于1000 的個數減去大于等于 1500 的個數，從而實現區間統計

2. F3 單元格中的公式隻要将區間數據稍加變通即可：

=SUM(COUNTIF($C$2:$C$24,{">=1500",">=2000"})*{1,-1})

在 E7 單元格中計算整個數據表中的非重複姓名數。

1. 在 E7 單元格中輸入以下公式 --> 按 Ctrl Shift Enter 結束：

=SUM(1/COUNTIF(B2:B24,B2:B24))

公式釋義：

• COUNTIF(B2:B24,B2:B24)：統計 B2:B24 區域中，每個名字出現的次數；本例的結果為 {3;4;2;4;4;2;1;3;3;4;2;4;4;4;4;3;4;3;4;4;2;4;3}
• 1/COUNTIF(B2:B24,B2:B24)：用 1 除以上述數組，得到一組分數
• SUM(1/COUNTIF(B2:B24,B2:B24))：将以上分數相加，就是每個名字出現的唯一次數。比如，“趙鐵錘”出現過 3 次，數組中就會有 3 個 1/3，sum 求和的結果正好為 1
• 數組公式，需要按三鍵結束。

統計數據表區域内提成數不為空的單元格數。

統計非空單元格數可以使用函數 COUNTA。

1. 在 E11 單元格中輸入以下公式：

=COUNTA(C2:C24)

* counta 函數用于計算範圍中不為空的單元格的個數。由于 C2:C24 的非空單元格都是數值，所以本例也可以将 counta 替換為 count 函數。

如果用 countif 函數也能實現同樣的效果。

2. 在 E12 單元格中輸入以下公式：

=COUNTIF(C2:C24,"<>")

公式釋義：

• "<>"：表示非空
• COUNTIF(C2:C24,"<>")：統計參數區域内非空單元格的個數

統計數據表區域内提成為空的單元格數。

統計空單元格數同樣有專門的函數 countblank。

1. 在 F11 單元格中輸入以下公式：

=COUNTBLANK(C2:C24)

這個案例一樣也可以用 countif 函數來實現。

2. 在 F12 單元格中輸入以下公式：

=COUNTIF(C2:C24,"")

公式釋義：

• ""：表示空
• COUNTIF(C2:C24,"")：統計參數區域内空單元格的個數

很多同學會覺得 Excel 單個案例講解有些碎片化，初學者未必能完全理解和掌握。不少同學都希望有一套完整的圖文教學，從最基礎的概念開始，一步步由簡入繁、從入門到精通，系統化地講解 Excel 的各個知識點。

現在終于有了，以下專欄，從最基礎的操作和概念講起，用生動、有趣的案例帶大家逐一掌握 Excel 的操作技巧、快捷鍵大全、函數公式、數據透視表、圖表、打印技巧等……學完全本，你也能成為 Excel 高手。

更多精彩资讯请关注tft每日頭條，我们将持续为您更新最新资讯!