原創作者： 看見星光 周慶麟 轉自：EXCEL之家ExcelHome

工作中總會有一些奇葩的特殊需求，最讓人頭疼的莫過于将符合條件的多個結果全部放到一個單元格内，這種彙總方式，就是傳說中的“一勺燴”啊。

舉個例子，請看下圖。

A列是某公司部門名稱，B列是人員姓名。

要求将相同部門的人員姓名填入F列對應單元格，不同人名之間以逗号間隔。

看到這裡，想必有人在心裡嘀咕了：

小子啊，你這數據處理不規範啊，怎麼能把這麼多人名放一個單元格呢？這是違反數據規律，作死吧……

停停！！——

作為表哥表妹大軍中的一員，俺更深知表格數據生殺予奪從不在我，而在于那位老是闆着臉的……老闆。

言歸正傳，說說這道題的解法：

首先在C2輸入公式：

=IF(A2=A1,C1&","&B2,B2)

向下複制填充。

F2輸入公式：

=LOOKUP(1,0/(E2=$A$2:$A$9),C$2:C$9)

向下複制填充，得到最終結果。

這個解法使用了輔助列的方式。

C列為輔助列，是一個簡單的IF函數。

以C2的公式為例：

=IF(A2=A1,C1&","&B2,B2)

先判斷A2和A1的值是否相等，如果相等，則返回C1&","&B2，如果不等，則返回B2。

此處A2和A1的值不相等，因而公式返回B2的值"祝洪忠"。

在公式向下複制填充的過程中，該公式得出的結果，将被公式所在單元格下方的下一個公式所使用，于是形成人名累加的效果。

比如C3單元格公式：

=IF(A3=A2,C2&","&B3,B3)

A3和A2的值相等，返回真值C2&","&B3。

C2為上個公式所返回的結果B2（祝洪忠），B3的值是"星光"，所以C3最後結果為"祝洪忠,星光"。

輔助列公式輸入完成後，在F列使用了一個常用的LOOKUP函數套路，得到最終結果：

=LOOKUP(1,0/(E2=$A$2:$A$9),C$2:C$9)

LOOKUP的這個套路，忽略錯誤值，總是取得最後一個符合條件的結果，我們可以總結為：

=LOOKUP(1,0/(條件區域=指定條件),要返回的目标區域)

該公式以0/(E2=$A$2:$A$9)構建了一個由0和錯誤值#DIV/0!組成的内存數組，再用永遠大于0的1作為查找值，于是查找出最後一個滿足部門等于E2的C列結果，即A列最後一個廣告部所對應的C列值：C2。

如果你使用的是Excel2019或是Office365，那就可以使用TEXTJOIN函數了，這個函數在WPS2019中也有哦。在F2單元格輸入以下公式，按住SHift Ctrl不放，按回車，OK了。

=TEXTJOIN(",",1,IF(A$2:A$9=E2,B$2:B$9,""))

TEXTJOIN函數的用法為：

=TEXTJOIN(間隔符号,要不要忽略空單元格,要合并的内容)

公式中要合并的内容為：

IF(A$2:A$9=E2,B$2:B$9,"")

也就是如果A$2:A$9等于E2，就返回B$2:B$9對應的内容，否則返回空文本""，結果是一個傳說中的内存數組：

{"祝洪忠";"星光";"";"";"";"";"";""}

TEXTJOIN函數對IF函數得到的内存數組進行合并，第一參數指定使用間隔符号為逗号，第二參數使用1，表示忽略内存數組中的空文本。

更多精彩资讯请关注tft每日頭條，我们将持续为您更新最新资讯!